REBOL [
	author: 'chl
	date: 2003-12-01
]

deli: context [

	username: none
	password: none

	build-url: func [ x ] [
		rejoin [ http:// username ":" password "@del.icio.us/api/" x ]
	]

	pass-thru: func [ x ] [ x ]

	split: func [ x ] [ reduce [ parse/all x " " ] ]

	converters: [
		date 	to-date
		count 	to-integer
		time	to-time
		href	to-url
		text	pass-thru
		tag	split
	]

	attr: func [ s a /local x ] [
		parse s either a = 'text [
			[ thru ">" copy x to "</" ]
		] [	
			replace 
				copy [ to " " to a thru {="} copy x to {"} ] 
				'a 
				to-string a
		]
		do (select converters a) x
	]	

	attrs: func [ s as /local r ] [
		r: copy [] 
		foreach a as [ 
			append r attr s a 
		] 
		r
	]

	deli-wrap: func [ sfx tag as /local x s e ] [
		r: copy []
		s: rejoin [ "<" tag " " ]
		e: rejoin [ "</" tag ">" ] 
		parse read build-url sfx [
			any [ 
				to s copy x [ thru "/>" | thru e ] 
				( append r attrs x as ) 
			]
		]
		r
	]

	dates: does [ deli-wrap 'posts/dates 'date [ date count ] ]
	tags:  does [ deli-wrap 'tags/get 'tag [ tag count ] ]
	posts: does [ deli-wrap 'posts/get 'post [ time href tag description ] ]
	posts-for-day: func [ x ] [ deli-wrap join "posts/get?dt=" x 'post [ time href tag description ] ]
	posts-for-tag: func [ x ] [ deli-wrap join "posts/get?tag=" x 'post [ time href tag description ] ]
	posts-for-tag-and-day: func [ x y ] [ deli-wrap rejoin [ "posts/get?tag=" x "&dt=" y ] 'post [ time href tag description ] ]
	dates-for-tag: func [ x ] [ deli-wrap join "posts/dates?tag=" x 'date [ date count ] ] 

]